[Info-vax] Move SECURITY.AUDIT$JOURNAL off the system disk?

[Phillip Helbig---undress to reply]

In article <j1eosm$g54$1 at usenet01.boi.hp.com>, "Jilly" <jilly at hp.com>
writes: 

> > My other question remains: Does
> >
> > $ SET 
> > AUDIT/JOURNAL=SECURITY/DESTINATION=CLUSTER_MANAGER:SECURITY.AUDIT$JOURNAL
> >
> > need to be done just once or at each system startup?
> >
> 
> Just once. 

Thanks.

Basically, there are two reasons for moving files off the system disk: 
in order to have common files among several system disks and to save 
space/reduce load on the system disk.  Of course, in some cases both 
reasons might be valid.  Of course, another aspect of this is that such 
files are often the "personality" of a cluster.  If all such files are 
off the system disk, then the system disk can be copied and used in 
another cluster with at most minimal changes.

SYS$MANAGER:SYLOGICALS.TEMPLATE has a list of files which can be moved 
by defining logical names (and creating files at the new location).  
There are some other files for which additional steps are necessary.  
Also, there are the TCPIP configuration files.

Does anyone have a definitive list of ALL such files?

This is what I have now, in a procedure called from
SYS$MANAGER:SYLOGICALS.COM.  Comments and corrections appreciated.  In 
particular, is there anything else I can move off the system disk?

$! CLUSTER_MANAGER:CLUSTER_WIDE_DEFS.COM
$!
$! This procedure is called from SYS$MANAGER:SYLOGICALS.COM as soon
$! as possible by all nodes when they are booted.  The disk on which it
$! resides is also mounted in SYS$MANAGER:SYLOGICALS.COM.
$!
$!
$  SET NOON
$!
$!
$! my own definitions
$!
$  CLUSTER_DEF                    :=   DEFINE/SYSTEM/EXECUTIVE_MODE/NOLOG
$  CLUSTER_DEF CLUSTER_DISK            DISK$USER:
$  CLUSTER_DEF CLUSTER_SYSTEM          CLUSTER_DISK:[SYSTEM.EXE]
$  CLUSTER_DEF CLUSTER_MANAGER         CLUSTER_DISK:[SYSTEM.MANAGER]
$  CLUSTER_DEF CLUSTER_LIBRARY         CLUSTER_DISK:[SYSTEM.LIBRARY]
$  CLUSTER_DEF CLUSTER_STARTUP         CLUSTER_DISK:[SYSTEM.STARTUP]
$  CLUSTER_DEF CLUSTER_TCPIP_SMTP      CLUSTER_DISK:[SYSTEM.TCPIP_SMTP]
$!
$!
$! definitions of common files (see SYS$MANAGER:SYLOGICALS.TEMPLATE)
$!
$  CLUSTER_DEF SYSUAF                  CLUSTER_SYSTEM:SYSUAF.DAT
$  CLUSTER_DEF SYSUAFALT               CLUSTER_SYSTEM:SYSUAFALT.DAT
$  CLUSTER_DEF SYSALF                  CLUSTER_SYSTEM:SYSALF.DAT
$  CLUSTER_DEF RIGHTSLIST              CLUSTER_SYSTEM:RIGHTSLIST.DAT
$  CLUSTER_DEF NETPROXY                CLUSTER_SYSTEM:NETPROXY.DAT
$  CLUSTER_DEF NET$PROXY               CLUSTER_SYSTEM:NET$PROXY.DAT
$  CLUSTER_DEF NETOBJECT               CLUSTER_SYSTEM:NETOBJECT.DAT
$  CLUSTER_DEF NETNODE_REMOTE          CLUSTER_SYSTEM:NETNODE_REMOTE.DAT
$  CLUSTER_DEF LMF$LICENSE             CLUSTER_SYSTEM:LMF$LICENSE.LDB
$  CLUSTER_DEF VMSMAIL_PROFILE         CLUSTER_SYSTEM:VMSMAIL_PROFILE.DATA
$  CLUSTER_DEF VMS$OBJECTS             CLUSTER_SYSTEM:VMS$OBJECTS.DAT
$  CLUSTER_DEF VMS$AUDIT_SERVER        CLUSTER_MANAGER:VMS$AUDIT_SERVER.DAT
$  CLUSTER_DEF VMS$PASSWORD_HISTORY    CLUSTER_SYSTEM:VMS$PASSWORD_HISTORY.DATA
$  CLUSTER_DEF VMS$PASSWORD_DICTIONARY CLUSTER_LIBRARY:VMS$PASSWORD_DICTIONARY.DATA
$  CLUSTER_DEF NETNODE_UPDATE          CLUSTER_MANAGER:NETNODE_UPDATE.COM
$  CLUSTER_DEF VMS$PASSWORD_POLICY     CLUSTER_LIBRARY:VMS$PASSWORD_POLICY.EXE
$  CLUSTER_DEF LAN$NODE_DATABASE       CLUSTER_SYSTEM:LAN$NODE_DATABASE.DAT
$  CLUSTER_DEF VMS$CLASS_SCHEDULE      CLUSTER_SYSTEM:VMS$CLASS_SCHEDULE.DATA
$  CLUSTER_DEF QMAN$MASTER             CLUSTER_SYSTEM
$!                                     QMAN$MASTER.DAT
$!                                     SYS$QUEUE_MANAGER.QMAN$QUEUES
$!                                     SYS$QUEUE_MANAGER.QMAN$JOURNAL
$!
$!
$! local symbol
$!
$  NODENAME = F$GETSYI("NODENAME")
$!
$!
$! similar stuff not in SYLOGICALS.TEMPLATE
$!
$  CLUSTER_DEF ACCOUNTNG        CLUSTER_MANAGER:ACCOUNTNG_'NODENAME'.DAT
$  CLUSTER_DEF VMS$AUDIT_SERVER CLUSTER_MANAGER:VMS$AUDIT_SERVER.DAT
$! see below for OPERATOR.LOG
$!
$!
$! similar stuff for TCPIP
$!
$  IF NODENAME .EQS. "DANEEL" !still testing
$  THEN
$    CLUSTER_DEF TCPIP$CONFIGURATION CLUSTER_SYSTEM:TCPIP$CONFIGURATION.DAT_VAX
$    CLUSTER_DEF TCPIP$HOST          CLUSTER_SYSTEM:TCPIP$HOST.DAT_VAX
$    CLUSTER_DEF TCPIP$PRINTCAP      CLUSTER_SYSTEM:TCPIP$PRINTCAP.DAT_VAX
$    CLUSTER_DEF TCPIP$NETWORK       CLUSTER_SYSTEM:TCPIP$NETWORK.DAT_VAX
$    CLUSTER_DEF TCPIP$PROXY         CLUSTER_SYSTEM:TCPIP$PROXY.DAT_VAX
$    CLUSTER_DEF TCPIP$ROUTE         CLUSTER_SYSTEM:TCPIP$ROUTE.DAT_VAX
$    CLUSTER_DEF TCPIP$SERVICE       CLUSTER_SYSTEM:TCPIP$SERVICE.DAT_VAX
$  ENDIF
$!
$!
$! stuff which one would normally not want to repeat (i.e. only do at boot)
$!
$  IF .NOT. F$TRNLNM("ALREADY_DONE")
$  THEN
$    DEFINE/SYSTEM/NOLOG ALREADY_DONE TRUE
$    LICENSE LOAD
$    CLUSTER_DEF OPC$OPA0_ENABLE    TRUE
$    CLUSTER_DEF OPC$LOGFILE_ENABLE TRUE
$    CLUSTER_DEF OPC$ALLOW_INBOUND  TRUE
$    CLUSTER_DEF OPC$ALLOW_OUTBOUND TRUE
$    CLUSTER_DEF OPC$LOGFILE_NAME -
      CLUSTER_MANAGER:OPERATOR_'NODENAME'.LOG
$    OPEN/APPEND/SHARE BOOT_HISTORY CLUSTER_MANAGER:BOOT.HISTORY
$    WRITE BOOT_HISTORY "''F$GETSYI("BOOTTIME")' ''NODENAME'"
$    CLOSE BOOT_HISTORY
$    IF .NOT. F$TRNLNM("SYSMAN$NODE_TABLE","LNM$SYSTEM_DIRECTORY",,,,"TABLE") -
      THEN CREATE/NAME_TABLE/PARENT=LNM$SYSTEM_DIRECTORY SYSMAN$NODE_TABLE
$  ENDIF
$!
$!
$! other definitions
$!
$  DEFINE/SYSTEM/NOLOG/TRANSLATION_ATTRIBUTES=TERMINAL EVE$KEYPAD EDT
$  CLUSTER_DEF MAIL$SYSTEM_FLAGS 55 ! was 23---bit 5 means retry UAF
$  CLUSTER_DEF/TRAN=TERM SYS$NODE 'NODENAME'::
$  CLUSTER_DEF SHUTDOWN$VERBOSE TRUE
$! need to add NEWSRDR etc
$  DEFINE/SYSTEM/EXEC DISK$DOC       DISK$OVMSDOC071:
$  DEFINE/SYSTEM/EXEC DECW$BOOK      DISK$DOC:[DECW$BOOK]
$  DEFINE/SYSTEM/EXEC DECW$BOOKSHELF DECW$BOOK:LIBRARY.DECW$BOOKSHELF
$! probably obsolete since now in CLUSTER_STARTUP:TCPIP$SMTP_SYSTARTUP.COM
$  CLUSTER_DEF TCPIP$SMTP_COMMON SYS$SPECIFIC:[TCPIP$SMTP],-
    CLUSTER_TCPIP_SMTP
$!
$!
$! SYSMAN definitions
$!
$  @ CLUSTER_MANAGER:DEFINE_NODE_LIST.COM
$!
$!
$  EXIT