[Info-vax] Third node into 2-node cluster

[Phillip Helbig undress to reply]

In article <gg146jF4jbtU1 at mid.individual.net>, Hans Bachner
<hans at bachner.priv.at> writes: 

> > The easiest way is perhaps to set up the new machine as a satellite,
> > then clone the system disk, then change MODPARAMS.DAT to make it boot as
> > a bootserver rather than satellite.
> 
> Probably not, given the fact that OpenVS is already installed on the new 
> servers.

In that case, yes, I agree.

I recommend a three-member shadow set, one on each node, for the "main 
user disk" and the same setup (could even be the same disk) for the 
"main cluster disk".  Mount it in SYLOGICALS.COM then call a procedure 
on the non-system disk to do all the definitions etc.  Here is my 
version:

$ SET PREFIX "(!11%D !11%T) "
$! CLUSTER_MANAGER:CLUSTER_WIDE_DEFS.COM
$!
$! This procedure is called from SYS$MANAGER:SYLOGICALS.COM as soon
$! as possible by all nodes when they are booted.
$!
$  WSO := WRITE SYS$OUTPUT
$!
$  WSO ""
$  WSO "Executing CLUSTER_SYSTEM:CLUSTER_WIDE_DEFS.COM"
$  WSO ""
$!
$  SET NOON
$!
$!
$! my own definitions
$!
$  CLUSTER_DEF                    :=   DEFINE/SYSTEM/EXECUTIVE_MODE/NOLOG
$  CLUSTER_DEF CLUSTER_DISK            DISK$USER:
$  CLUSTER_DEF CLUSTER_SYSTEM          CLUSTER_DISK:[SYSTEM.EXE]
$  CLUSTER_DEF CLUSTER_MANAGER         CLUSTER_DISK:[SYSTEM.MANAGER]
$  CLUSTER_DEF CLUSTER_LIBRARY         CLUSTER_DISK:[SYSTEM.LIBRARY]
$  CLUSTER_DEF CLUSTER_STARTUP         CLUSTER_DISK:[SYSTEM.STARTUP]
$  CLUSTER_DEF CLUSTER_TCPIP_SMTP      CLUSTER_DISK:[SYSTEM.TCPIP_SMTP]
$!
$!
$! definitions of common files (see SYS$MANAGER:SYLOGICALS.TEMPLATE)
$!
$  CLUSTER_DEF SYSUAF                  CLUSTER_SYSTEM:SYSUAF.DAT
$  CLUSTER_DEF SYSUAFALT               CLUSTER_SYSTEM:SYSUAFALT.DAT
$  CLUSTER_DEF SYSALF                  CLUSTER_SYSTEM:SYSALF.DAT
$  CLUSTER_DEF RIGHTSLIST              CLUSTER_SYSTEM:RIGHTSLIST.DAT
$  CLUSTER_DEF NETPROXY                CLUSTER_SYSTEM:NETPROXY.DAT
$  CLUSTER_DEF NET$PROXY               CLUSTER_SYSTEM:NET$PROXY.DAT
$  CLUSTER_DEF NETOBJECT               CLUSTER_SYSTEM:NETOBJECT.DAT
$  CLUSTER_DEF NETNODE_REMOTE          CLUSTER_SYSTEM:NETNODE_REMOTE.DAT
$  CLUSTER_DEF LMF$LICENSE             CLUSTER_SYSTEM:LMF$LICENSE.LDB
$  CLUSTER_DEF VMSMAIL_PROFILE         CLUSTER_SYSTEM:VMSMAIL_PROFILE.DATA
$  CLUSTER_DEF VMS$OBJECTS             CLUSTER_SYSTEM:VMS$OBJECTS.DAT
$  CLUSTER_DEF VMS$AUDIT_SERVER        CLUSTER_MANAGER:VMS$AUDIT_SERVER.DAT
$  CLUSTER_DEF VMS$PASSWORD_HISTORY    CLUSTER_SYSTEM:VMS$PASSWORD_HISTORY.DATA
$  CLUSTER_DEF VMS$PASSWORD_DICTIONARY CLUSTER_LIBRARY:VMS$PASSWORD_DICTIONARY.DATA
$  CLUSTER_DEF NETNODE_UPDATE          CLUSTER_MANAGER:NETNODE_UPDATE.COM
$  CLUSTER_DEF VMS$PASSWORD_POLICY     CLUSTER_LIBRARY:VMS$PASSWORD_POLICY.EXE
$  CLUSTER_DEF LAN$NODE_DATABASE       CLUSTER_SYSTEM:LAN$NODE_DATABASE.DAT
$  CLUSTER_DEF VMS$CLASS_SCHEDULE      CLUSTER_SYSTEM:VMS$CLASS_SCHEDULE.DATA
$  CLUSTER_DEF QMAN$MASTER             CLUSTER_SYSTEM
$!                                     QMAN$MASTER.DAT
$!                                     SYS$QUEUE_MANAGER.QMAN$QUEUES
$!                                     SYS$QUEUE_MANAGER.QMAN$JOURNAL
$!
$!
$! local symbol
$!
$  NODENAME = F$GETSYI("NODENAME")
$!
$!
$! similar stuff not in SYLOGICALS.TEMPLATE
$!
$  CLUSTER_DEF ACCOUNTNG        CLUSTER_MANAGER:ACCOUNTNG_'NODENAME'.DAT
$  CLUSTER_DEF VMS$AUDIT_SERVER CLUSTER_MANAGER:VMS$AUDIT_SERVER.DAT
$!
$!
$! similar stuff for TCPIP
$!
$ CLUSTER_DEF TCPIP$CONFIGURATION CLUSTER_SYSTEM:TCPIP$CONFIGURATION.DAT
$ CLUSTER_DEF TCPIP$BOOTP         CLUSTER_SYSTEM:TCPIP$BOOTP.DAT
$ CLUSTER_DEF TCPIP$HOST          CLUSTER_SYSTEM:TCPIP$HOST.DAT
$ CLUSTER_DEF TCPIP$NETWORK       CLUSTER_SYSTEM:TCPIP$NETWORK.DAT
$ CLUSTER_DEF TCPIP$PROXY         CLUSTER_SYSTEM:TCPIP$PROXY.DAT
$ CLUSTER_DEF TCPIP$ROUTE         CLUSTER_SYSTEM:TCPIP$ROUTE.DAT
$ CLUSTER_DEF TCPIP$SERVICE       CLUSTER_SYSTEM:TCPIP$SERVICE.DAT
$ CLUSTER_DEF TCPIP$PRINTCAP      CLUSTER_SYSTEM:TCPIP$PRINTCAP.DAT
$!
$!
$! stuff which one would normally not want to repeat (i.e. only do at boot)
$!
$  IF .NOT. F$TRNLNM("CLUSTER_WIDE_DEFS_ALREADY_DONE")
$  THEN
$    DEFINE/SYSTEM/NOLOG CLUSTER_WIDE_DEFS_ALREADY_DONE TRUE
$    LICENSE LOAD
$    CLUSTER_DEF OPC$OPA0_ENABLE    TRUE
$    CLUSTER_DEF OPC$LOGFILE_ENABLE TRUE
$    CLUSTER_DEF OPC$ALLOW_INBOUND  TRUE
$    CLUSTER_DEF OPC$ALLOW_OUTBOUND TRUE
$    CLUSTER_DEF OPC$LOGFILE_NAME -
      CLUSTER_MANAGER:OPERATOR_'NODENAME'.LOG
$    OPEN/APPEND/SHARE BOOT_HISTORY CLUSTER_MANAGER:BOOT.HISTORY
$    WRITE BOOT_HISTORY "''F$GETSYI("BOOTTIME")' ''NODENAME' ''F$TIME()' STARTUP" 
$    CLOSE BOOT_HISTORY
$    IF .NOT. F$TRNLNM("SYSMAN$NODE_TABLE","LNM$SYSTEM_DIRECTORY",,,,"TABLE") -
      THEN CREATE/NAME_TABLE/PARENT=LNM$SYSTEM_DIRECTORY SYSMAN$NODE_TABLE
$  ENDIF
$!
$!
$! other definitions
$!
$  DEFINE/SYSTEM/NOLOG/TRANSLATION_ATTRIBUTES=TERMINAL EVE$KEYPAD EDT
$  CLUSTER_DEF MAIL$SYSTEM_FLAGS 55 ! was 23---bit 5 means retry UAF
$  CLUSTER_DEF/TRAN=TERM SYS$NODE 'NODENAME'::
$  CLUSTER_DEF/TRAN=CON TCPIP_ROOT_'NODENAME' DISK$USER:['NODENAME'.]
$  CLUSTER_DEF SHUTDOWN$VERBOSE TRUE
$  DEFINE/SYSTEM/EXEC DISK$DOC       DISK$OVMSDOC071:
$  DEFINE/SYSTEM/EXEC DECW$BOOK      DISK$DOC:[DECW$BOOK]
$  DEFINE/SYSTEM/EXEC DECW$BOOKSHELF DECW$BOOK:LIBRARY.DECW$BOOKSHELF
$! probably obsolete since now in CLUSTER_STARTUP:TCPIP$SMTP_SYSTARTUP.COM
$  CLUSTER_DEF TCPIP$SMTP_COMMON SYS$SPECIFIC:[TCPIP$SMTP],-
    CLUSTER_TCPIP_SMTP
$!
$!
$! SYSMAN definitions
$!
$  @ CLUSTER_MANAGER:DEFINE_NODE_LIST.COM
$!
$!
$  EXIT
$!----------